375e894038
* Make Frame Processors an extra subspec * Update VisionCamera.podspec * Make optional * Make VisionCamera compile without Skia * Fix * Add skia again * Update VisionCamera.podspec * Make VisionCamera build without Frame Processors * Rename error to `system/frame-processors-unavailable` * Fix Frame Processor returning early * Remove `preset`, FP partial rewrite * Only warn on frame drop * Fix wrong queue * fix: Run on CameraQueue again * Update CameraView.swift * fix: Activate audio session asynchronously on audio queue * Update CameraView+RecordVideo.swift * Update PreviewView.h * Cleanups * Cleanup * fix cast * feat: Add LiDAR Depth Camera support * Upgrade Ruby * Add vector icons type * Update Gemfile.lock * fix: Stop queues on deinit * Also load `builtInTrueDepthCamera` * Update CameraViewManager.swift * Update SkImageHelpers.mm * Extract FrameProcessorCallback to FrameProcessor Holds more context now :) * Rename to .m * fix: Add `RCTLog` import * Create SkiaFrameProcessor * Update CameraBridge.h * Call Frame Processor * Fix defines * fix: Allow deleting callback funcs * fix Skia build * batch * Just call `setSkiaFrameProcessor` * Rewrite in Swift * Pass `SkiaRenderer` * Fix Import * Move `PreviewView` to Swift * Fix Layer * Set Skia Canvas to Frame Host Object * Make `DrawableFrameHostObject` subclass * Fix TS types * Use same MTLDevice and apply scale * Make getter * Extract `setTorch` and `Preview` * fix: Fix nil metal device * Don't wait for session stop in deinit * Use main pixel ratio * Use unique_ptr for Render Contexts * fix: Fix SkiaPreviewDisplayLink broken after deinit * inline `getTextureCache` * Update CameraPage.tsx * chore: Format iOS * perf: Allow MTLLayer to be optimized for only frame buffers * Add RN Video types * fix: Fix Frame Processors if guard * Find nodeModules recursively * Create `Frame.isDrawable` * Add `cocoapods-check` dependency
62 lines
2.0 KiB
Plaintext
62 lines
2.0 KiB
Plaintext
//
|
|
// FrameProcessor.mm
|
|
// VisionCamera
|
|
//
|
|
// Created by Marc Rousavy on 13.07.23.
|
|
// Copyright © 2023 mrousavy. All rights reserved.
|
|
//
|
|
|
|
#import <Foundation/Foundation.h>
|
|
#import "FrameProcessor.h"
|
|
|
|
#import <memory>
|
|
#import <jsi/jsi.h>
|
|
#import "WKTJsiWorklet.h"
|
|
#import "FrameHostObject.h"
|
|
|
|
using namespace facebook;
|
|
|
|
@implementation FrameProcessor {
|
|
std::shared_ptr<RNWorklet::JsiWorkletContext> _workletContext;
|
|
std::shared_ptr<RNWorklet::WorkletInvoker> _workletInvoker;
|
|
}
|
|
|
|
- (instancetype)initWithWorklet:(std::shared_ptr<RNWorklet::JsiWorkletContext>)context
|
|
worklet:(std::shared_ptr<RNWorklet::JsiWorklet>)worklet {
|
|
if (self = [super init]) {
|
|
_workletContext = context;
|
|
_workletInvoker = std::make_shared<RNWorklet::WorkletInvoker>(worklet);
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (void)callWithFrameHostObject:(std::shared_ptr<FrameHostObject>)frameHostObject {
|
|
// Call the Frame Processor on the Worklet Runtime
|
|
jsi::Runtime& runtime = _workletContext->getWorkletRuntime();
|
|
|
|
try {
|
|
// Wrap HostObject as JSI Value
|
|
auto argument = jsi::Object::createFromHostObject(runtime, frameHostObject);
|
|
jsi::Value jsValue(std::move(argument));
|
|
|
|
// Call the Worklet with the Frame JS Host Object as an argument
|
|
_workletInvoker->call(runtime, jsi::Value::undefined(), &jsValue, 1);
|
|
} catch (jsi::JSError& jsError) {
|
|
// JS Error occured, print it to console.
|
|
auto message = jsError.getMessage();
|
|
|
|
_workletContext->invokeOnJsThread([message](jsi::Runtime& jsRuntime) {
|
|
auto logFn = jsRuntime.global().getPropertyAsObject(jsRuntime, "console").getPropertyAsFunction(jsRuntime, "error");
|
|
logFn.call(jsRuntime, jsi::String::createFromUtf8(jsRuntime, "Frame Processor threw an error: " + message));
|
|
});
|
|
}
|
|
}
|
|
|
|
- (void)call:(Frame* _Nonnull)frame {
|
|
// Create the Frame Host Object wrapping the internal Frame
|
|
auto frameHostObject = std::make_shared<FrameHostObject>(frame);
|
|
[self callWithFrameHostObject:frameHostObject];
|
|
}
|
|
|
|
@end
|