From 4b76bd73c85d9df383f90902e2232c94177ff04e Mon Sep 17 00:00:00 2001
From: Ivan Malison <IvanMalison@gmail.com>
Date: Fri, 10 May 2019 11:23:56 -0700
Subject: [PATCH] [NixOS] Add slack with appindicator support

---
 nixos/extra.nix    |   1 -
 nixos/overlays.nix |   1 +
 nixos/slack.nix    | 116 +++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 117 insertions(+), 1 deletion(-)
 create mode 100644 nixos/slack.nix

diff --git a/nixos/extra.nix b/nixos/extra.nix
index fea876b6..9ff007a7 100644
--- a/nixos/extra.nix
+++ b/nixos/extra.nix
@@ -4,7 +4,6 @@
     gimp
     android-studio
     texlive.combined.scheme-full
-    slack
   ];
   boot.extraModulePackages = with pkgs; [ xboxdrv ];
 }
diff --git a/nixos/overlays.nix b/nixos/overlays.nix
index 67705fb5..c2f41b4c 100644
--- a/nixos/overlays.nix
+++ b/nixos/overlays.nix
@@ -19,6 +19,7 @@ self: super:
   pasystray-appindicator = super.pasystray.overrideAttrs (oldAttrs: rec {
     buildInputs = oldAttrs.buildInputs ++ [self.libappindicator-gtk3];
   });
+  slack-appindicator = self.callPackage ./slack.nix { };
   customizable-notify-osd = super.notify-osd.overrideAttrs (oldAttrs: rec {
     version = "0.9.35+16.04.20160415";
     baseURI = "https://launchpad.net/~leolik/+archive/leolik";
diff --git a/nixos/slack.nix b/nixos/slack.nix
new file mode 100644
index 00000000..de879413
--- /dev/null
+++ b/nixos/slack.nix
@@ -0,0 +1,116 @@
+{ darkMode ? false, stdenv, fetchurl, dpkg, makeWrapper , alsaLib, atk, cairo,
+cups, curl, dbus, expat, fontconfig, freetype, glib , gnome2, gtk3, gdk_pixbuf,
+libappindicator-gtk3, libnotify, libxcb, nspr, nss, pango , systemd, xorg,
+at-spi2-atk }:
+
+let
+
+  version = "3.4.0";
+
+  rpath = stdenv.lib.makeLibraryPath [
+    alsaLib
+    at-spi2-atk
+    atk
+    cairo
+    cups
+    curl
+    dbus
+    expat
+    fontconfig
+    freetype
+    glib
+    gnome2.GConf
+    gdk_pixbuf
+    gtk3
+    pango
+    libnotify
+    libxcb
+    libappindicator-gtk3
+    nspr
+    nss
+    stdenv.cc.cc
+    systemd
+
+    xorg.libxkbfile
+    xorg.libX11
+    xorg.libXcomposite
+    xorg.libXcursor
+    xorg.libXdamage
+    xorg.libXext
+    xorg.libXfixes
+    xorg.libXi
+    xorg.libXrandr
+    xorg.libXrender
+    xorg.libXtst
+    xorg.libXScrnSaver
+  ] + ":${stdenv.cc.cc.lib}/lib64";
+
+  src =
+    if stdenv.hostPlatform.system == "x86_64-linux" then
+      fetchurl {
+        url = "https://downloads.slack-edge.com/linux_releases/slack-desktop-${version}-amd64.deb";
+        sha256 = "0ld53gg0dbfpi79lz2sx5br29mlhwkfcypzf3iya4cm75a33hyw5";
+      }
+    else
+      throw "Slack is not supported on ${stdenv.hostPlatform.system}";
+
+in stdenv.mkDerivation {
+  name = "slack-${version}";
+
+  inherit src;
+
+  buildInputs = [
+    dpkg
+    gtk3  # needed for GSETTINGS_SCHEMAS_PATH
+  ];
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  unpackPhase = "true";
+  buildCommand = ''
+    mkdir -p $out
+    dpkg -x $src $out
+    cp -av $out/usr/* $out
+    rm -rf $out/etc $out/usr $out/share/lintian
+
+    # Otherwise it looks "suspicious"
+    chmod -R g-w $out
+
+    for file in $(find $out -type f \( -perm /0111 -o -name \*.so\* \) ); do
+      patchelf --set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" "$file" || true
+      patchelf --set-rpath ${rpath}:$out/lib/slack $file || true
+    done
+
+    # Replace the broken bin/slack symlink with a startup wrapper
+    rm $out/bin/slack
+    makeWrapper $out/lib/slack/slack $out/bin/slack \
+      --prefix XDG_DATA_DIRS : $GSETTINGS_SCHEMAS_PATH
+
+    # Fix the desktop link
+    substituteInPlace $out/share/applications/slack.desktop \
+      --replace /usr/bin/ $out/bin/ \
+      --replace /usr/share/ $out/share/
+  '' + stdenv.lib.optionalString darkMode ''
+    cat <<EOF >> $out/lib/slack/resources/app.asar.unpacked/src/static/ssb-interop.js
+    document.addEventListener('DOMContentLoaded', function() {
+    let tt__customCss = ".menu ul li a:not(.inline_menu_link) {color: #fff !important;}"
+    $.ajax({
+        url: 'https://cdn.rawgit.com/laCour/slack-night-mode/master/css/raw/black.css',
+        success: function(css) {
+            \$("<style></style>").appendTo('head').html(css + tt__customCss);
+            \$("<style></style>").appendTo('head').html('#reply_container.upload_in_threads .inline_message_input_container {background: padding-box #545454}');
+            \$("<style></style>").appendTo('head').html('.p-channel_sidebar {background: #363636 !important}');
+            \$("<style></style>").appendTo('head').html('#client_body:not(.onboarding):not(.feature_global_nav_layout):before {background: inherit;}');
+        }
+      });
+    });
+    EOF
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Desktop client for Slack";
+    homepage = https://slack.com;
+    license = licenses.unfree;
+    platforms = [ "x86_64-linux" ];
+  };
+}