chore: Move everything into package/ (#1745)

* Move everything into package * Remove .DS_Store * Move scripts and eslintrc to package * Create CODE_OF_CONDUCT.md * fix some links * Update all links (I think) * Update generated docs * Update notice-yarn-changes.yml * Update validate-android.yml * Update validate-cpp.yml * Delete notice-yarn-changes.yml * Update validate-cpp.yml * Update validate-cpp.yml * Update validate-js.yml * Update validate-cpp.yml * Update validate-cpp.yml * wrong c++ style * Revert "wrong c++ style" This reverts commit 55a3575589c6f13f8b05134d83384f55e0601ab2.
2023-09-01 18:15:28 +02:00
parent 2a5c33323b
commit 036856aed5
347 changed files with 3088 additions and 154 deletions
--- a/Processor/Frame.h
+++ b/Processor/Frame.h
@@ -0,0 +1,23 @@
+//
+//  Frame.h
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 15.03.21.
+//  Copyright © 2021 mrousavy. All rights reserved.
+//
+
+#pragma once
+
+#import <CoreMedia/CMSampleBuffer.h>
+#import <Foundation/Foundation.h>
+#import <UIKit/UIImage.h>
+
+@interface Frame : NSObject
+
+- (instancetype _Nonnull)initWithBuffer:(CMSampleBufferRef _Nonnull)buffer
+                            orientation:(UIImageOrientation)orientation;
+
+@property(nonatomic, readonly) CMSampleBufferRef _Nonnull buffer;
+@property(nonatomic, readonly) UIImageOrientation orientation;
+
+@end
--- a/Processor/Frame.m
+++ b/Processor/Frame.m
@@ -0,0 +1,31 @@
+//
+//  Frame.m
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 08.06.21.
+//  Copyright © 2021 mrousavy. All rights reserved.
+//
+
+#import "Frame.h"
+#import <CoreMedia/CMSampleBuffer.h>
+#import <Foundation/Foundation.h>
+
+@implementation Frame {
+  CMSampleBufferRef _Nonnull buffer;
+  UIImageOrientation orientation;
+}
+
+- (instancetype)initWithBuffer:(CMSampleBufferRef _Nonnull)buffer
+                   orientation:(UIImageOrientation)orientation {
+  self = [super init];
+  if (self) {
+    _buffer = buffer;
+    _orientation = orientation;
+  }
+  return self;
+}
+
+@synthesize buffer = _buffer;
+@synthesize orientation = _orientation;
+
+@end
--- a/Processor/FrameHostObject.h
+++ b/Processor/FrameHostObject.h
@@ -0,0 +1,28 @@
+//
+//  FrameHostObject.h
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 22.03.21.
+//  Copyright © 2021 mrousavy. All rights reserved.
+//
+
+#pragma once
+
+#import <CoreMedia/CMSampleBuffer.h>
+#import <jsi/jsi.h>
+
+#import "Frame.h"
+
+using namespace facebook;
+
+class JSI_EXPORT FrameHostObject : public jsi::HostObject {
+public:
+  explicit FrameHostObject(Frame* frame) : frame(frame) {}
+
+public:
+  jsi::Value get(jsi::Runtime&, const jsi::PropNameID& name) override;
+  std::vector<jsi::PropNameID> getPropertyNames(jsi::Runtime& rt) override;
+
+public:
+  Frame* frame;
+};
--- a/Processor/FrameHostObject.mm
+++ b/Processor/FrameHostObject.mm
@@ -0,0 +1,188 @@
+//
+//  FrameHostObject.m
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 22.03.21.
+//  Copyright © 2021 mrousavy. All rights reserved.
+//
+
+#import "FrameHostObject.h"
+#import "WKTJsiHostObject.h"
+#import <Foundation/Foundation.h>
+#import <jsi/jsi.h>
+
+#import "../../cpp/JSITypedArray.h"
+
+std::vector<jsi::PropNameID> FrameHostObject::getPropertyNames(jsi::Runtime& rt) {
+  std::vector<jsi::PropNameID> result;
+  result.push_back(jsi::PropNameID::forUtf8(rt, std::string("width")));
+  result.push_back(jsi::PropNameID::forUtf8(rt, std::string("height")));
+  result.push_back(jsi::PropNameID::forUtf8(rt, std::string("bytesPerRow")));
+  result.push_back(jsi::PropNameID::forUtf8(rt, std::string("planesCount")));
+  result.push_back(jsi::PropNameID::forUtf8(rt, std::string("orientation")));
+  result.push_back(jsi::PropNameID::forUtf8(rt, std::string("isMirrored")));
+  result.push_back(jsi::PropNameID::forUtf8(rt, std::string("timestamp")));
+  result.push_back(jsi::PropNameID::forUtf8(rt, std::string("pixelFormat")));
+  // Conversion
+  result.push_back(jsi::PropNameID::forUtf8(rt, std::string("toString")));
+  result.push_back(jsi::PropNameID::forUtf8(rt, std::string("toArrayBuffer")));
+  // Ref Management
+  result.push_back(jsi::PropNameID::forUtf8(rt, std::string("isValid")));
+  result.push_back(jsi::PropNameID::forUtf8(rt, std::string("incrementRefCount")));
+  result.push_back(jsi::PropNameID::forUtf8(rt, std::string("decrementRefCount")));
+
+  return result;
+}
+
+jsi::Value FrameHostObject::get(jsi::Runtime& runtime, const jsi::PropNameID& propName) {
+  auto name = propName.utf8(runtime);
+
+  if (name == "toString") {
+    auto toString = JSI_HOST_FUNCTION_LAMBDA {
+      if (this->frame == nil) {
+        return jsi::String::createFromUtf8(runtime, "[closed frame]");
+      }
+      auto imageBuffer = CMSampleBufferGetImageBuffer(frame.buffer);
+      auto width = CVPixelBufferGetWidth(imageBuffer);
+      auto height = CVPixelBufferGetHeight(imageBuffer);
+
+      NSMutableString* string =
+          [NSMutableString stringWithFormat:@"%lu x %lu Frame", width, height];
+      return jsi::String::createFromUtf8(runtime, string.UTF8String);
+    };
+    return jsi::Function::createFromHostFunction(
+        runtime, jsi::PropNameID::forUtf8(runtime, "toString"), 0, toString);
+  }
+  if (name == "incrementRefCount") {
+    auto incrementRefCount = JSI_HOST_FUNCTION_LAMBDA {
+      // Increment retain count by one so ARC doesn't destroy the Frame Buffer.
+      CFRetain(frame.buffer);
+      return jsi::Value::undefined();
+    };
+    return jsi::Function::createFromHostFunction(
+        runtime, jsi::PropNameID::forUtf8(runtime, "incrementRefCount"), 0, incrementRefCount);
+  }
+  if (name == "decrementRefCount") {
+    auto decrementRefCount = JSI_HOST_FUNCTION_LAMBDA {
+      // Decrement retain count by one. If the retain count is zero, ARC will destroy the Frame
+      // Buffer.
+      CFRelease(frame.buffer);
+      return jsi::Value::undefined();
+    };
+    return jsi::Function::createFromHostFunction(
+        runtime, jsi::PropNameID::forUtf8(runtime, "decrementRefCount"), 0, decrementRefCount);
+  }
+  if (name == "toArrayBuffer") {
+    auto toArrayBuffer = JSI_HOST_FUNCTION_LAMBDA {
+      auto pixelBuffer = CMSampleBufferGetImageBuffer(frame.buffer);
+      auto bytesPerRow = CVPixelBufferGetBytesPerRow(pixelBuffer);
+      auto height = CVPixelBufferGetHeight(pixelBuffer);
+
+      auto arraySize = bytesPerRow * height;
+
+      static constexpr auto ARRAYBUFFER_CACHE_PROP_NAME = "__frameArrayBufferCache";
+      if (!runtime.global().hasProperty(runtime, ARRAYBUFFER_CACHE_PROP_NAME)) {
+        vision::TypedArray<vision::TypedArrayKind::Uint8ClampedArray> arrayBuffer(runtime,
+                                                                                  arraySize);
+        runtime.global().setProperty(runtime, ARRAYBUFFER_CACHE_PROP_NAME, arrayBuffer);
+      }
+
+      auto arrayBufferCache =
+          runtime.global().getPropertyAsObject(runtime, ARRAYBUFFER_CACHE_PROP_NAME);
+      auto arrayBuffer = vision::getTypedArray(runtime, arrayBufferCache)
+                             .get<vision::TypedArrayKind::Uint8ClampedArray>(runtime);
+
+      if (arrayBuffer.size(runtime) != arraySize) {
+        arrayBuffer =
+            vision::TypedArray<vision::TypedArrayKind::Uint8ClampedArray>(runtime, arraySize);
+        runtime.global().setProperty(runtime, ARRAYBUFFER_CACHE_PROP_NAME, arrayBuffer);
+      }
+
+      CVPixelBufferLockBaseAddress(pixelBuffer, kCVPixelBufferLock_ReadOnly);
+      auto buffer = (uint8_t*)CVPixelBufferGetBaseAddress(pixelBuffer);
+      arrayBuffer.updateUnsafe(runtime, buffer, arraySize);
+      CVPixelBufferUnlockBaseAddress(pixelBuffer, kCVPixelBufferLock_ReadOnly);
+
+      return arrayBuffer;
+    };
+    return jsi::Function::createFromHostFunction(
+        runtime, jsi::PropNameID::forUtf8(runtime, "toArrayBuffer"), 0, toArrayBuffer);
+  }
+
+  if (name == "isValid") {
+    auto isValid = frame != nil && frame.buffer != nil && CFGetRetainCount(frame.buffer) > 0 &&
+                   CMSampleBufferIsValid(frame.buffer);
+    return jsi::Value(isValid);
+  }
+  if (name == "width") {
+    auto imageBuffer = CMSampleBufferGetImageBuffer(frame.buffer);
+    auto width = CVPixelBufferGetWidth(imageBuffer);
+    return jsi::Value((double)width);
+  }
+  if (name == "height") {
+    auto imageBuffer = CMSampleBufferGetImageBuffer(frame.buffer);
+    auto height = CVPixelBufferGetHeight(imageBuffer);
+    return jsi::Value((double)height);
+  }
+  if (name == "orientation") {
+    switch (frame.orientation) {
+      case UIImageOrientationUp:
+      case UIImageOrientationUpMirrored:
+        return jsi::String::createFromUtf8(runtime, "portrait");
+      case UIImageOrientationDown:
+      case UIImageOrientationDownMirrored:
+        return jsi::String::createFromUtf8(runtime, "portrait-upside-down");
+      case UIImageOrientationLeft:
+      case UIImageOrientationLeftMirrored:
+        return jsi::String::createFromUtf8(runtime, "landscape-left");
+      case UIImageOrientationRight:
+      case UIImageOrientationRightMirrored:
+        return jsi::String::createFromUtf8(runtime, "landscape-right");
+    }
+  }
+  if (name == "isMirrored") {
+    switch (frame.orientation) {
+      case UIImageOrientationUp:
+      case UIImageOrientationDown:
+      case UIImageOrientationLeft:
+      case UIImageOrientationRight:
+        return jsi::Value(false);
+      case UIImageOrientationDownMirrored:
+      case UIImageOrientationUpMirrored:
+      case UIImageOrientationLeftMirrored:
+      case UIImageOrientationRightMirrored:
+        return jsi::Value(true);
+    }
+  }
+  if (name == "timestamp") {
+    auto timestamp = CMSampleBufferGetPresentationTimeStamp(frame.buffer);
+    auto seconds = static_cast<double>(CMTimeGetSeconds(timestamp));
+    return jsi::Value(seconds * 1000.0);
+  }
+  if (name == "pixelFormat") {
+    auto format = CMSampleBufferGetFormatDescription(frame.buffer);
+    auto mediaType = CMFormatDescriptionGetMediaSubType(format);
+    switch (mediaType) {
+      case kCVPixelFormatType_32BGRA:
+        return jsi::String::createFromUtf8(runtime, "rgb");
+      case kCVPixelFormatType_420YpCbCr8BiPlanarFullRange:
+      case kCVPixelFormatType_420YpCbCr8BiPlanarVideoRange:
+        return jsi::String::createFromUtf8(runtime, "yuv");
+      default:
+        return jsi::String::createFromUtf8(runtime, "unknown");
+    }
+  }
+  if (name == "bytesPerRow") {
+    auto imageBuffer = CMSampleBufferGetImageBuffer(frame.buffer);
+    auto bytesPerRow = CVPixelBufferGetBytesPerRow(imageBuffer);
+    return jsi::Value((double)bytesPerRow);
+  }
+  if (name == "planesCount") {
+    auto imageBuffer = CMSampleBufferGetImageBuffer(frame.buffer);
+    auto planesCount = CVPixelBufferGetPlaneCount(imageBuffer);
+    return jsi::Value((double)planesCount);
+  }
+
+  // fallback to base implementation
+  return HostObject::get(runtime, propName);
+}
--- a/Processor/FrameProcessor.h
+++ b/Processor/FrameProcessor.h
@@ -0,0 +1,33 @@
+//
+//  FrameProcessorContext.h
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 13.07.23.
+//  Copyright © 2023 mrousavy. All rights reserved.
+//
+
+#pragma once
+
+#import "Frame.h"
+#import <AVFoundation/AVFoundation.h>
+#import <Foundation/Foundation.h>
+
+#ifdef __cplusplus
+#import "FrameHostObject.h"
+#import "WKTJsiWorklet.h"
+#import <jsi/jsi.h>
+#import <memory.h>
+#endif
+
+@interface FrameProcessor : NSObject
+
+#ifdef __cplusplus
+- (instancetype _Nonnull)initWithWorklet:(std::shared_ptr<RNWorklet::JsiWorklet>)worklet
+                                 context:(std::shared_ptr<RNWorklet::JsiWorkletContext>)context;
+
+- (void)callWithFrameHostObject:(std::shared_ptr<FrameHostObject>)frameHostObject;
+#endif
+
+- (void)call:(Frame* _Nonnull)frame;
+
+@end
--- a/Processor/FrameProcessor.mm
+++ b/Processor/FrameProcessor.mm
@@ -0,0 +1,64 @@
+//
+//  FrameProcessor.mm
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 13.07.23.
+//  Copyright © 2023 mrousavy. All rights reserved.
+//
+
+#import "FrameProcessor.h"
+#import <Foundation/Foundation.h>
+
+#import "FrameHostObject.h"
+#import "WKTJsiWorklet.h"
+#import <jsi/jsi.h>
+#import <memory>
+
+using namespace facebook;
+
+@implementation FrameProcessor {
+  std::shared_ptr<RNWorklet::JsiWorkletContext> _workletContext;
+  std::shared_ptr<RNWorklet::WorkletInvoker> _workletInvoker;
+}
+
+- (instancetype)initWithWorklet:(std::shared_ptr<RNWorklet::JsiWorklet>)worklet
+                        context:(std::shared_ptr<RNWorklet::JsiWorkletContext>)context {
+  if (self = [super init]) {
+    _workletInvoker = std::make_shared<RNWorklet::WorkletInvoker>(worklet);
+    _workletContext = context;
+  }
+  return self;
+}
+
+- (void)callWithFrameHostObject:(std::shared_ptr<FrameHostObject>)frameHostObject {
+  // Call the Frame Processor on the Worklet Runtime
+  jsi::Runtime& runtime = _workletContext->getWorkletRuntime();
+
+  try {
+    // Wrap HostObject as JSI Value
+    auto argument = jsi::Object::createFromHostObject(runtime, frameHostObject);
+    jsi::Value jsValue(std::move(argument));
+
+    // Call the Worklet with the Frame JS Host Object as an argument
+    _workletInvoker->call(runtime, jsi::Value::undefined(), &jsValue, 1);
+  } catch (jsi::JSError& jsError) {
+    // JS Error occured, print it to console.
+    auto message = jsError.getMessage();
+
+    _workletContext->invokeOnJsThread([message](jsi::Runtime& jsRuntime) {
+      auto logFn = jsRuntime.global()
+                       .getPropertyAsObject(jsRuntime, "console")
+                       .getPropertyAsFunction(jsRuntime, "error");
+      logFn.call(jsRuntime, jsi::String::createFromUtf8(
+                                jsRuntime, "Frame Processor threw an error: " + message));
+    });
+  }
+}
+
+- (void)call:(Frame* _Nonnull)frame {
+  // Create the Frame Host Object wrapping the internal Frame
+  auto frameHostObject = std::make_shared<FrameHostObject>(frame);
+  [self callWithFrameHostObject:frameHostObject];
+}
+
+@end
--- a/Processor/FrameProcessorPlugin.h
+++ b/Processor/FrameProcessorPlugin.h
@@ -0,0 +1,28 @@
+//
+//  FrameProcessorPlugin.h
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 01.05.21.
+//  Copyright © 2021 mrousavy. All rights reserved.
+//
+
+#pragma once
+
+#import "Frame.h"
+#import <Foundation/Foundation.h>
+
+/// The base class for a Frame Processor Plugin which can be called synchronously from a JS Frame
+/// Processor.
+///
+/// Subclass this class in a Swift or Objective-C class and override the `callback:withArguments:`
+/// method, and implement your Frame Processing there.
+///
+/// Use `[FrameProcessorPluginRegistry addFrameProcessorPlugin:]` to register the Plugin to the
+/// VisionCamera Runtime.
+@interface FrameProcessorPlugin : NSObject
+
+/// The actual callback when calling this plugin. Any Frame Processing should be handled there.
+/// Make sure your code is optimized, as this is a hot path.
+- (id _Nullable)callback:(Frame* _Nonnull)frame withArguments:(NSDictionary* _Nullable)arguments;
+
+@end
--- a/Processor/FrameProcessorPlugin.m
+++ b/Processor/FrameProcessorPlugin.m
@@ -0,0 +1,22 @@
+//
+//  FrameProcessorPlugin.m
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 31.07.23.
+//  Copyright © 2023 mrousavy. All rights reserved.
+//
+
+#import "FrameProcessorPlugin.h"
+
+// Base implementation (empty)
+@implementation FrameProcessorPlugin
+
+- (id _Nullable)callback:(Frame* _Nonnull)frame withArguments:(NSDictionary* _Nullable)arguments {
+  [NSException
+       raise:NSInternalInconsistencyException
+      format:
+          @"Frame Processor Plugin does not override the `callback(frame:withArguments:)` method!"];
+  return nil;
+}
+
+@end
--- a/Processor/FrameProcessorPluginHostObject.h
+++ b/Processor/FrameProcessorPluginHostObject.h
@@ -0,0 +1,32 @@
+//
+//  FrameProcessorPluginHostObject.h
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 21.07.23.
+//  Copyright © 2023 mrousavy. All rights reserved.
+//
+
+#pragma once
+
+#import "FrameProcessorPlugin.h"
+#import <ReactCommon/CallInvoker.h>
+#import <jsi/jsi.h>
+#import <memory>
+
+using namespace facebook;
+
+class FrameProcessorPluginHostObject : public jsi::HostObject {
+public:
+  explicit FrameProcessorPluginHostObject(FrameProcessorPlugin* plugin,
+                                          std::shared_ptr<react::CallInvoker> callInvoker)
+      : _plugin(plugin), _callInvoker(callInvoker) {}
+  ~FrameProcessorPluginHostObject() {}
+
+public:
+  std::vector<jsi::PropNameID> getPropertyNames(jsi::Runtime& runtime) override;
+  jsi::Value get(jsi::Runtime& runtime, const jsi::PropNameID& name) override;
+
+private:
+  FrameProcessorPlugin* _plugin;
+  std::shared_ptr<react::CallInvoker> _callInvoker;
+};
--- a/Processor/FrameProcessorPluginHostObject.mm
+++ b/Processor/FrameProcessorPluginHostObject.mm
@@ -0,0 +1,55 @@
+//
+//  FrameProcessorPluginHostObject.mm
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 21.07.23.
+//  Copyright © 2023 mrousavy. All rights reserved.
+//
+
+#import "FrameProcessorPluginHostObject.h"
+#import "FrameHostObject.h"
+#import "JSINSObjectConversion.h"
+#import <Foundation/Foundation.h>
+#import <vector>
+
+using namespace facebook;
+
+std::vector<jsi::PropNameID>
+FrameProcessorPluginHostObject::getPropertyNames(jsi::Runtime& runtime) {
+  std::vector<jsi::PropNameID> result;
+  result.push_back(jsi::PropNameID::forUtf8(runtime, std::string("call")));
+  return result;
+}
+
+jsi::Value FrameProcessorPluginHostObject::get(jsi::Runtime& runtime,
+                                               const jsi::PropNameID& propName) {
+  auto name = propName.utf8(runtime);
+
+  if (name == "call") {
+    return jsi::Function::createFromHostFunction(
+        runtime, jsi::PropNameID::forUtf8(runtime, "call"), 2,
+        [=](jsi::Runtime& runtime, const jsi::Value& thisValue, const jsi::Value* arguments,
+            size_t count) -> jsi::Value {
+          // Frame is first argument
+          auto frameHostObject =
+              arguments[0].asObject(runtime).asHostObject<FrameHostObject>(runtime);
+          Frame* frame = frameHostObject->frame;
+
+          // Options are second argument (possibly undefined)
+          NSDictionary* options = nil;
+          if (count > 1) {
+            auto optionsObject = arguments[1].asObject(runtime);
+            options = JSINSObjectConversion::convertJSIObjectToNSDictionary(runtime, optionsObject,
+                                                                            _callInvoker);
+          }
+
+          // Call actual Frame Processor Plugin
+          id result = [_plugin callback:frame withArguments:nil];
+
+          // Convert result value to jsi::Value (possibly undefined)
+          return JSINSObjectConversion::convertObjCObjectToJSIValue(runtime, result);
+        });
+  }
+
+  return jsi::Value::undefined();
+}
--- a/Processor/FrameProcessorPluginRegistry.h
+++ b/Processor/FrameProcessorPluginRegistry.h
@@ -0,0 +1,26 @@
+//
+//  FrameProcessorPluginRegistry.h
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 24.03.21.
+//  Copyright © 2021 mrousavy. All rights reserved.
+//
+
+#pragma once
+
+#import "Frame.h"
+#import "FrameProcessorPlugin.h"
+#import <Foundation/Foundation.h>
+
+@interface FrameProcessorPluginRegistry : NSObject
+
+typedef FrameProcessorPlugin* _Nonnull (^PluginInitializerFunction)(
+    NSDictionary* _Nullable options);
+
+ (void)addFrameProcessorPlugin:(NSString* _Nonnull)name
+                withInitializer:(PluginInitializerFunction _Nonnull)pluginInitializer;
+
+ (FrameProcessorPlugin* _Nullable)getPlugin:(NSString* _Nonnull)name
+                                 withOptions:(NSDictionary* _Nullable)options;
+
+@end
--- a/Processor/FrameProcessorPluginRegistry.m
+++ b/Processor/FrameProcessorPluginRegistry.m
@@ -0,0 +1,46 @@
+//
+//  FrameProcessorPluginRegistry.m
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 24.03.21.
+//  Copyright © 2021 mrousavy. All rights reserved.
+//
+
+#import "FrameProcessorPluginRegistry.h"
+#import <Foundation/Foundation.h>
+
+@implementation FrameProcessorPluginRegistry
+
+ (NSMutableDictionary<NSString*, PluginInitializerFunction>*)frameProcessorPlugins {
+  static NSMutableDictionary<NSString*, PluginInitializerFunction>* plugins = nil;
+  if (plugins == nil) {
+    plugins = [[NSMutableDictionary alloc] init];
+  }
+  return plugins;
+}
+
+ (void)addFrameProcessorPlugin:(NSString*)name
+                withInitializer:(PluginInitializerFunction)pluginInitializer {
+  BOOL alreadyExists =
+      [[FrameProcessorPluginRegistry frameProcessorPlugins] valueForKey:name] != nil;
+  NSAssert(!alreadyExists,
+           @"Tried to add a Frame Processor Plugin with a name that already exists! Either choose "
+           @"unique names, or "
+           @"remove the unused plugin. Name: %@",
+           name);
+
+  [[FrameProcessorPluginRegistry frameProcessorPlugins] setValue:pluginInitializer forKey:name];
+}
+
+ (FrameProcessorPlugin*)getPlugin:(NSString* _Nonnull)name
+                       withOptions:(NSDictionary* _Nullable)options {
+  PluginInitializerFunction initializer =
+      [[FrameProcessorPluginRegistry frameProcessorPlugins] objectForKey:name];
+  if (initializer == nil) {
+    return nil;
+  }
+
+  return initializer(options);
+}
+
+@end
--- a/Processor/JSINSObjectConversion.h
+++ b/Processor/JSINSObjectConversion.h
@@ -0,0 +1,65 @@
+//
+//  JSINSObjectConversion.h
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 30.04.21.
+//  Copyright © 2021 mrousavy. All rights reserved.
+//
+
+#pragma once
+
+#import <React/RCTBridgeModule.h>
+#import <ReactCommon/CallInvoker.h>
+#import <jsi/jsi.h>
+
+namespace JSINSObjectConversion {
+
+using namespace facebook;
+using namespace facebook::react;
+
+// NSNumber -> boolean
+jsi::Value convertNSNumberToJSIBoolean(jsi::Runtime& runtime, NSNumber* value);
+
+// NSNumber -> number
+jsi::Value convertNSNumberToJSINumber(jsi::Runtime& runtime, NSNumber* value);
+
+// NSNumber -> string
+jsi::String convertNSStringToJSIString(jsi::Runtime& runtime, NSString* value);
+
+// NSDictionary -> {}
+jsi::Object convertNSDictionaryToJSIObject(jsi::Runtime& runtime, NSDictionary* value);
+
+// NSArray -> []
+jsi::Array convertNSArrayToJSIArray(jsi::Runtime& runtime, NSArray* value);
+
+// id -> ???
+jsi::Value convertObjCObjectToJSIValue(jsi::Runtime& runtime, id value);
+
+// string -> NSString
+NSString* convertJSIStringToNSString(jsi::Runtime& runtime, const jsi::String& value);
+
+// any... -> NSArray
+NSArray* convertJSICStyleArrayToNSArray(jsi::Runtime& runtime, const jsi::Value* array,
+                                        size_t length, std::shared_ptr<CallInvoker> jsInvoker);
+
+// NSArray -> any...
+jsi::Value* convertNSArrayToJSICStyleArray(jsi::Runtime& runtime, NSArray* array);
+
+// [] -> NSArray
+NSArray* convertJSIArrayToNSArray(jsi::Runtime& runtime, const jsi::Array& value,
+                                  std::shared_ptr<CallInvoker> jsInvoker);
+
+// {} -> NSDictionary
+NSDictionary* convertJSIObjectToNSDictionary(jsi::Runtime& runtime, const jsi::Object& value,
+                                             std::shared_ptr<CallInvoker> jsInvoker);
+
+// any -> id
+id convertJSIValueToObjCObject(jsi::Runtime& runtime, const jsi::Value& value,
+                               std::shared_ptr<CallInvoker> jsInvoker);
+
+// (any...) => any -> (void)(id, id)
+RCTResponseSenderBlock convertJSIFunctionToCallback(jsi::Runtime& runtime,
+                                                    const jsi::Function& value,
+                                                    std::shared_ptr<CallInvoker> jsInvoker);
+
+} // namespace JSINSObjectConversion
--- a/Processor/JSINSObjectConversion.mm
+++ b/Processor/JSINSObjectConversion.mm
@@ -0,0 +1,216 @@
+//
+//  JSINSObjectConversion.mm
+//  VisionCamera
+//
+//  Forked and Adjusted by Marc Rousavy on 02.05.21.
+//  Copyright © 2021 mrousavy & Facebook. All rights reserved.
+//
+//  Forked and adjusted from:
+//  https://github.com/facebook/react-native/blob/900210cacc4abca0079e3903781bc223c80c8ac7/ReactCommon/react/nativemodule/core/platform/ios/RCTTurboModule.mm
+//  Original Copyright Notice:
+//
+//  Copyright (c) Facebook, Inc. and its affiliates.
+//
+//  This source code is licensed under the MIT license found in the
+//  LICENSE file in the root directory of this source tree.
+//
+
+#import "JSINSObjectConversion.h"
+#import "../Frame Processor/Frame.h"
+#import "../Frame Processor/FrameHostObject.h"
+#import <Foundation/Foundation.h>
+#import <React/RCTBridge.h>
+#import <ReactCommon/CallInvoker.h>
+#import <ReactCommon/RCTBlockGuard.h>
+#import <ReactCommon/TurboModuleUtils.h>
+#import <jsi/jsi.h>
+
+using namespace facebook;
+using namespace facebook::react;
+
+namespace JSINSObjectConversion {
+
+jsi::Value convertNSNumberToJSIBoolean(jsi::Runtime& runtime, NSNumber* value) {
+  return jsi::Value((bool)[value boolValue]);
+}
+
+jsi::Value convertNSNumberToJSINumber(jsi::Runtime& runtime, NSNumber* value) {
+  return jsi::Value([value doubleValue]);
+}
+
+jsi::String convertNSStringToJSIString(jsi::Runtime& runtime, NSString* value) {
+  return jsi::String::createFromUtf8(runtime, [value UTF8String] ?: "");
+}
+
+jsi::Object convertNSDictionaryToJSIObject(jsi::Runtime& runtime, NSDictionary* value) {
+  jsi::Object result = jsi::Object(runtime);
+  for (NSString* k in value) {
+    result.setProperty(runtime, [k UTF8String], convertObjCObjectToJSIValue(runtime, value[k]));
+  }
+  return result;
+}
+
+jsi::Array convertNSArrayToJSIArray(jsi::Runtime& runtime, NSArray* value) {
+  jsi::Array result = jsi::Array(runtime, value.count);
+  for (size_t i = 0; i < value.count; i++) {
+    result.setValueAtIndex(runtime, i, convertObjCObjectToJSIValue(runtime, value[i]));
+  }
+  return result;
+}
+
+jsi::Value convertObjCObjectToJSIValue(jsi::Runtime& runtime, id value) {
+  if (value == nil) {
+    return jsi::Value::undefined();
+  } else if ([value isKindOfClass:[NSString class]]) {
+    return convertNSStringToJSIString(runtime, (NSString*)value);
+  } else if ([value isKindOfClass:[NSNumber class]]) {
+    if ([value isKindOfClass:[@YES class]]) {
+      return convertNSNumberToJSIBoolean(runtime, (NSNumber*)value);
+    }
+    return convertNSNumberToJSINumber(runtime, (NSNumber*)value);
+  } else if ([value isKindOfClass:[NSDictionary class]]) {
+    return convertNSDictionaryToJSIObject(runtime, (NSDictionary*)value);
+  } else if ([value isKindOfClass:[NSArray class]]) {
+    return convertNSArrayToJSIArray(runtime, (NSArray*)value);
+  } else if (value == (id)kCFNull) {
+    return jsi::Value::null();
+  } else if ([value isKindOfClass:[Frame class]]) {
+    auto frameHostObject = std::make_shared<FrameHostObject>((Frame*)value);
+    return jsi::Object::createFromHostObject(runtime, frameHostObject);
+  }
+  return jsi::Value::undefined();
+}
+
+NSString* convertJSIStringToNSString(jsi::Runtime& runtime, const jsi::String& value) {
+  return [NSString stringWithUTF8String:value.utf8(runtime).c_str()];
+}
+
+NSArray* convertJSICStyleArrayToNSArray(jsi::Runtime& runtime, const jsi::Value* array,
+                                        size_t length, std::shared_ptr<CallInvoker> jsInvoker) {
+  if (length < 1)
+    return @[];
+  NSMutableArray* result = [NSMutableArray new];
+  for (size_t i = 0; i < length; i++) {
+    // Insert kCFNull when it's `undefined` value to preserve the indices.
+    [result addObject:convertJSIValueToObjCObject(runtime, array[i], jsInvoker) ?: (id)kCFNull];
+  }
+  return [result copy];
+}
+
+jsi::Value* convertNSArrayToJSICStyleArray(jsi::Runtime& runtime, NSArray* array) {
+  auto result = new jsi::Value[array.count];
+  for (size_t i = 0; i < array.count; i++) {
+    result[i] = convertObjCObjectToJSIValue(runtime, array[i]);
+  }
+  return result;
+}
+
+NSArray* convertJSIArrayToNSArray(jsi::Runtime& runtime, const jsi::Array& value,
+                                  std::shared_ptr<CallInvoker> jsInvoker) {
+  size_t size = value.size(runtime);
+  NSMutableArray* result = [NSMutableArray new];
+  for (size_t i = 0; i < size; i++) {
+    // Insert kCFNull when it's `undefined` value to preserve the indices.
+    [result
+        addObject:convertJSIValueToObjCObject(runtime, value.getValueAtIndex(runtime, i), jsInvoker)
+                      ?: (id)kCFNull];
+  }
+  return [result copy];
+}
+
+NSDictionary* convertJSIObjectToNSDictionary(jsi::Runtime& runtime, const jsi::Object& value,
+                                             std::shared_ptr<CallInvoker> jsInvoker) {
+  jsi::Array propertyNames = value.getPropertyNames(runtime);
+  size_t size = propertyNames.size(runtime);
+  NSMutableDictionary* result = [NSMutableDictionary new];
+  for (size_t i = 0; i < size; i++) {
+    jsi::String name = propertyNames.getValueAtIndex(runtime, i).getString(runtime);
+    NSString* k = convertJSIStringToNSString(runtime, name);
+    id v = convertJSIValueToObjCObject(runtime, value.getProperty(runtime, name), jsInvoker);
+    if (v) {
+      result[k] = v;
+    }
+  }
+  return [result copy];
+}
+
+id convertJSIValueToObjCObject(jsi::Runtime& runtime, const jsi::Value& value,
+                               std::shared_ptr<CallInvoker> jsInvoker) {
+  if (value.isUndefined() || value.isNull()) {
+    return nil;
+  }
+  if (value.isBool()) {
+    return @(value.getBool());
+  }
+  if (value.isNumber()) {
+    return @(value.getNumber());
+  }
+  if (value.isString()) {
+    return convertJSIStringToNSString(runtime, value.getString(runtime));
+  }
+  if (value.isObject()) {
+    jsi::Object o = value.getObject(runtime);
+    if (o.isArray(runtime)) {
+      return convertJSIArrayToNSArray(runtime, o.getArray(runtime), jsInvoker);
+    }
+    if (o.isFunction(runtime)) {
+      return convertJSIFunctionToCallback(runtime, std::move(o.getFunction(runtime)), jsInvoker);
+    }
+    if (o.isHostObject(runtime)) {
+      auto hostObject = o.asHostObject(runtime);
+      auto frame = dynamic_cast<FrameHostObject*>(hostObject.get());
+      if (frame != nullptr) {
+        return frame->frame;
+      }
+    }
+    return convertJSIObjectToNSDictionary(runtime, o, jsInvoker);
+  }
+
+  throw std::runtime_error("Unsupported jsi::jsi::Value kind");
+}
+
+RCTResponseSenderBlock convertJSIFunctionToCallback(jsi::Runtime& runtime,
+                                                    const jsi::Function& value,
+                                                    std::shared_ptr<CallInvoker> jsInvoker) {
+  auto weakWrapper = CallbackWrapper::createWeak(value.getFunction(runtime), runtime, jsInvoker);
+  RCTBlockGuard* blockGuard = [[RCTBlockGuard alloc] initWithCleanup:^() {
+    auto strongWrapper = weakWrapper.lock();
+    if (strongWrapper) {
+      strongWrapper->destroy();
+    }
+  }];
+
+  BOOL __block wrapperWasCalled = NO;
+  RCTResponseSenderBlock callback = ^(NSArray* responses) {
+    if (wrapperWasCalled) {
+      throw std::runtime_error("callback arg cannot be called more than once");
+    }
+
+    auto strongWrapper = weakWrapper.lock();
+    if (!strongWrapper) {
+      return;
+    }
+
+    strongWrapper->jsInvoker().invokeAsync([weakWrapper, responses, blockGuard]() {
+      auto strongWrapper2 = weakWrapper.lock();
+      if (!strongWrapper2) {
+        return;
+      }
+
+      const jsi::Value* args = convertNSArrayToJSICStyleArray(strongWrapper2->runtime(), responses);
+      strongWrapper2->callback().call(strongWrapper2->runtime(), args,
+                                      static_cast<size_t>(responses.count));
+      strongWrapper2->destroy();
+      delete[] args;
+
+      // Delete the CallbackWrapper when the block gets dealloced without being invoked.
+      (void)blockGuard;
+    });
+
+    wrapperWasCalled = YES;
+  };
+
+  return [callback copy];
+}
+
+} // namespace JSINSObjectConversion
--- a/Processor/VisionCameraProxy.h
+++ b/Processor/VisionCameraProxy.h
@@ -0,0 +1,45 @@
+//
+//  VisionCameraProxy.h
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 20.07.23.
+//  Copyright © 2023 mrousavy. All rights reserved.
+//
+
+#pragma once
+
+#import <Foundation/Foundation.h>
+#import <React/RCTBridge.h>
+
+#ifdef __cplusplus
+#import "WKTJsiWorkletContext.h"
+#import <ReactCommon/CallInvoker.h>
+#import <jsi/jsi.h>
+
+using namespace facebook;
+
+class VisionCameraProxy : public jsi::HostObject {
+public:
+  explicit VisionCameraProxy(jsi::Runtime& runtime,
+                             std::shared_ptr<react::CallInvoker> callInvoker);
+  ~VisionCameraProxy();
+
+public:
+  std::vector<jsi::PropNameID> getPropertyNames(jsi::Runtime& runtime) override;
+  jsi::Value get(jsi::Runtime& runtime, const jsi::PropNameID& name) override;
+
+private:
+  void setFrameProcessor(jsi::Runtime& runtime, int viewTag, const jsi::Object& frameProcessor);
+  void removeFrameProcessor(jsi::Runtime& runtime, int viewTag);
+  jsi::Value getFrameProcessorPlugin(jsi::Runtime& runtime, std::string name,
+                                     const jsi::Object& options);
+
+private:
+  std::shared_ptr<RNWorklet::JsiWorkletContext> _workletContext;
+  std::shared_ptr<react::CallInvoker> _callInvoker;
+};
+#endif
+
+@interface VisionCameraInstaller : NSObject
+ (BOOL)installToBridge:(RCTBridge* _Nonnull)bridge;
+@end
--- a/Processor/VisionCameraProxy.mm
+++ b/Processor/VisionCameraProxy.mm
@@ -0,0 +1,178 @@
+//
+//  VisionCameraProxy.mm
+//  VisionCamera
+//
+//  Created by Marc Rousavy on 20.07.23.
+//  Copyright © 2023 mrousavy. All rights reserved.
+//
+
+#import "VisionCameraProxy.h"
+#import <Foundation/Foundation.h>
+#import <jsi/jsi.h>
+
+#import "../../cpp/JSITypedArray.h"
+#import "FrameHostObject.h"
+#import "FrameProcessor.h"
+#import "FrameProcessorPluginHostObject.h"
+#import "FrameProcessorPluginRegistry.h"
+#import "JSINSObjectConversion.h"
+#import "WKTJsiWorklet.h"
+
+#import <React/RCTBridge+Private.h>
+#import <React/RCTBridge.h>
+#import <React/RCTUIManager.h>
+#import <React/RCTUtils.h>
+#import <ReactCommon/RCTTurboModuleManager.h>
+
+// Swift forward-declarations
+__attribute__((objc_runtime_name("_TtC12VisionCamera12CameraQueues")))
+@interface CameraQueues : NSObject
+@property(nonatomic, class, readonly, strong) dispatch_queue_t _Nonnull videoQueue;
+@end
+
+__attribute__((objc_runtime_name("_TtC12VisionCamera10CameraView")))
+@interface CameraView : UIView
+@property(nonatomic, copy) FrameProcessor* _Nullable frameProcessor;
+@end
+
+using namespace facebook;
+
+VisionCameraProxy::VisionCameraProxy(jsi::Runtime& runtime,
+                                     std::shared_ptr<react::CallInvoker> callInvoker) {
+  _callInvoker = callInvoker;
+
+  NSLog(@"VisionCameraProxy: Creating Worklet Context...");
+  auto runOnJS = [callInvoker](std::function<void()>&& f) {
+    // Run on React JS Runtime
+    callInvoker->invokeAsync(std::move(f));
+  };
+  auto runOnWorklet = [](std::function<void()>&& f) {
+    // Run on Frame Processor Worklet Runtime
+    dispatch_async(CameraQueues.videoQueue, [f = std::move(f)]() { f(); });
+  };
+
+  _workletContext = std::make_shared<RNWorklet::JsiWorkletContext>("VisionCamera", &runtime,
+                                                                   runOnJS, runOnWorklet);
+  NSLog(@"VisionCameraProxy: Worklet Context Created!");
+}
+
+VisionCameraProxy::~VisionCameraProxy() {
+  NSLog(@"VisionCameraProxy: Destroying context...");
+  // Destroy ArrayBuffer cache for both the JS and the Worklet Runtime.
+  vision::invalidateArrayBufferCache(*_workletContext->getJsRuntime());
+  vision::invalidateArrayBufferCache(_workletContext->getWorkletRuntime());
+}
+
+std::vector<jsi::PropNameID> VisionCameraProxy::getPropertyNames(jsi::Runtime& runtime) {
+  std::vector<jsi::PropNameID> result;
+  result.push_back(jsi::PropNameID::forUtf8(runtime, std::string("setFrameProcessor")));
+  result.push_back(jsi::PropNameID::forUtf8(runtime, std::string("removeFrameProcessor")));
+  result.push_back(jsi::PropNameID::forUtf8(runtime, std::string("getFrameProcessorPlugin")));
+  return result;
+}
+
+void VisionCameraProxy::setFrameProcessor(jsi::Runtime& runtime, int viewTag,
+                                          const jsi::Object& object) {
+  auto frameProcessorType = object.getProperty(runtime, "type").asString(runtime).utf8(runtime);
+  auto worklet = std::make_shared<RNWorklet::JsiWorklet>(
+      runtime, object.getProperty(runtime, "frameProcessor"));
+
+  RCTExecuteOnMainQueue(^{
+    auto currentBridge = [RCTBridge currentBridge];
+    auto anonymousView =
+        [currentBridge.uiManager viewForReactTag:[NSNumber numberWithDouble:viewTag]];
+    auto view = static_cast<CameraView*>(anonymousView);
+    if (frameProcessorType == "frame-processor") {
+      view.frameProcessor = [[FrameProcessor alloc] initWithWorklet:worklet
+                                                            context:_workletContext];
+    } else {
+      throw std::runtime_error("Unknown FrameProcessor.type passed! Received: " +
+                               frameProcessorType);
+    }
+  });
+}
+
+void VisionCameraProxy::removeFrameProcessor(jsi::Runtime& runtime, int viewTag) {
+  RCTExecuteOnMainQueue(^{
+    auto currentBridge = [RCTBridge currentBridge];
+    auto anonymousView =
+        [currentBridge.uiManager viewForReactTag:[NSNumber numberWithDouble:viewTag]];
+    auto view = static_cast<CameraView*>(anonymousView);
+    view.frameProcessor = nil;
+  });
+}
+
+jsi::Value VisionCameraProxy::getFrameProcessorPlugin(jsi::Runtime& runtime, std::string name,
+                                                      const jsi::Object& options) {
+  NSString* key = [NSString stringWithUTF8String:name.c_str()];
+  NSDictionary* optionsObjc =
+      JSINSObjectConversion::convertJSIObjectToNSDictionary(runtime, options, _callInvoker);
+  FrameProcessorPlugin* plugin = [FrameProcessorPluginRegistry getPlugin:key
+                                                             withOptions:optionsObjc];
+  if (plugin == nil) {
+    return jsi::Value::undefined();
+  }
+
+  auto pluginHostObject = std::make_shared<FrameProcessorPluginHostObject>(plugin, _callInvoker);
+  return jsi::Object::createFromHostObject(runtime, pluginHostObject);
+}
+
+jsi::Value VisionCameraProxy::get(jsi::Runtime& runtime, const jsi::PropNameID& propName) {
+  auto name = propName.utf8(runtime);
+
+  if (name == "setFrameProcessor") {
+    return jsi::Function::createFromHostFunction(
+        runtime, jsi::PropNameID::forUtf8(runtime, "setFrameProcessor"), 1,
+        [this](jsi::Runtime& runtime, const jsi::Value& thisValue, const jsi::Value* arguments,
+               size_t count) -> jsi::Value {
+          auto viewTag = arguments[0].asNumber();
+          auto object = arguments[1].asObject(runtime);
+          this->setFrameProcessor(runtime, static_cast<int>(viewTag), object);
+          return jsi::Value::undefined();
+        });
+  }
+  if (name == "removeFrameProcessor") {
+    return jsi::Function::createFromHostFunction(
+        runtime, jsi::PropNameID::forUtf8(runtime, "removeFrameProcessor"), 1,
+        [this](jsi::Runtime& runtime, const jsi::Value& thisValue, const jsi::Value* arguments,
+               size_t count) -> jsi::Value {
+          auto viewTag = arguments[0].asNumber();
+          this->removeFrameProcessor(runtime, static_cast<int>(viewTag));
+          return jsi::Value::undefined();
+        });
+  }
+  if (name == "getFrameProcessorPlugin") {
+    return jsi::Function::createFromHostFunction(
+        runtime, jsi::PropNameID::forUtf8(runtime, "getFrameProcessorPlugin"), 1,
+        [this](jsi::Runtime& runtime, const jsi::Value& thisValue, const jsi::Value* arguments,
+               size_t count) -> jsi::Value {
+          if (count < 1 || !arguments[0].isString()) {
+            throw jsi::JSError(runtime, "First argument needs to be a string (pluginName)!");
+          }
+          auto pluginName = arguments[0].asString(runtime).utf8(runtime);
+          auto options = count > 1 ? arguments[1].asObject(runtime) : jsi::Object(runtime);
+
+          return this->getFrameProcessorPlugin(runtime, pluginName, options);
+        });
+  }
+
+  return jsi::Value::undefined();
+}
+
+@implementation VisionCameraInstaller
+ (BOOL)installToBridge:(RCTBridge* _Nonnull)bridge {
+  RCTCxxBridge* cxxBridge = (RCTCxxBridge*)[RCTBridge currentBridge];
+  if (!cxxBridge.runtime) {
+    return NO;
+  }
+
+  jsi::Runtime& runtime = *(jsi::Runtime*)cxxBridge.runtime;
+
+  // global.VisionCameraProxy
+  auto visionCameraProxy = std::make_shared<VisionCameraProxy>(runtime, bridge.jsCallInvoker);
+  runtime.global().setProperty(runtime, "VisionCameraProxy",
+                               jsi::Object::createFromHostObject(runtime, visionCameraProxy));
+
+  return YES;
+}
+@end